DS2450/OWDS2450.S

   1
   2 // Copyright (c) 2015, Tobias Mueller tm(at)tm3d.de
   3 // All rights reserved.
   4 //
   5 // Redistribution and use in source and binary forms, with or without
   6 // modification, are permitted provided that the following conditions are
   7 // met:
   8 //
   9 //  * Redistributions of source code must retain the above copyright
  10 //    notice, this list of conditions and the following disclaimer.
  11 //  * Redistributions in binary form must reproduce the above copyright
  12 //    notice, this list of conditions and the following disclaimer in the
  13 //    documentation and/or other materials provided with the
  14 //    distribution.
  15 //  * All advertising materials mentioning features or use of this
  16 //    software must display the following acknowledgement: This product
  17 //    includes software developed by tm3d.de and its contributors.
  18 //  * Neither the name of tm3d.de nor the names of its contributors may
  19 //    be used to endorse or promote products derived from this software
  20 //    without specific prior written permission.
  21 //
  22 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  23 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  24 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  25 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  26 // OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  27 // SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  28 // LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  29 // DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  30 // THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  31 // (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  32 // OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  33
  34 #define _CHANGEABLE_ID_
  35
  36 #include "../common/OWConfig.s"
  37 #include "../common/OWCRC16.s"
  38
  39 .extern pack,8
  40 .comm addr,1 ;zweites Adressbyte ist unnoetig (Warum auch immer fuer 32 Byte 16 Bit Adressen verwendet werden....)
  41 .comm crcsave,1 ; zwischenspeicherspeicher fuer crc nur zweites byte....
  42 //.extern  am2302_temp,2
  43
  44
  45
  46 .macro CHIP_INIT
  47 .endm
  48
  49 .macro COMMAND_TABLE
  50                 rjmp h_readmemoryaddr
  51                 rjmp h_readmemory
  52                 rjmp h_readmemorycrc1
  53                 rjmp h_readmemorycrc2
  54                 rjmp h_writememoryaddr
  55                 rjmp h_writememory
  56                 rjmp h_writememorycrc1
  57                 rjmp h_writememorycrc2
  58                 rjmp h_writememoryreadback
  59                 rjmp h_convert
  60                 rjmp h_convertcrc1
  61                 rjmp h_convertcrc2
  62 .endm
  63
  64 #include "../common/OWRomFunctions.s"
  65 #include "../common/OWTimerInterrupt.s"
  66
  67
  68
  69 ; Ab hier Geraeteabhaenging
  70 #define OW_READ_MEMORY_ADDR OW_FIRST_COMMAND+0
  71 #define OW_READ_MEMORY OW_FIRST_COMMAND+1
  72 #define OW_READ_MEMORY_CRC1 OW_FIRST_COMMAND+2
  73 #define OW_READ_MEMORY_CRC2 OW_FIRST_COMMAND+3
  74 #define OW_WRITE_MEMORY_ADDR OW_FIRST_COMMAND+4
  75 #define OW_WRITE_MEMORY OW_FIRST_COMMAND+5
  76 #define OW_WRITE_MEMORY_CRC1 OW_FIRST_COMMAND+6
  77 #define OW_WRITE_MEMORY_CRC2 OW_FIRST_COMMAND+7
  78 #define OW_WRITE_MEMORY_READBACK OW_FIRST_COMMAND+8
  79 #define OW_CONVERT OW_FIRST_COMMAND+9
  80 #define OW_CONVERT_CRC1 OW_FIRST_COMMAND+10
  81 #define OW_CONVERT_CRC2 OW_FIRST_COMMAND+11
  82
  83
  84 ;---------------------------------------------------
  85 ;       READ COMMAND and start operation
  86 ;---------------------------------------------------
  87
  88
  89 h_readcommand:
  90         clr r_bytep
  91 #ifndef _DIS_FLASH_
  92         FLASH_COMMANDS ; muss zu erst sein....
  93 #endif
  94         cset 0xAA,OW_READ_MEMORY_ADDR
  95         cset 0x55,OW_WRITE_MEMORY_ADDR
  96         cset 0x3C,OW_CONVERT
  97 #ifdef _CHANGEABLE_ID_
  98         CHANGE_ID_COMMANDS
  99 #endif
 100         ldi r_mode,OW_SLEEP
 101         rjmp handle_end
 102
 103
 104 h_readmemoryaddr:
 105         cpi r_bytep,0  ;erstes Adressbyte ?
 106         brne h_readmemory_addr_byte1 ;nein dann weiter
 107         andi r_rwbyte,0x1F  ; nur Adressen zwischen 0 und 0x1F zulassen
 108         sts addr,r_rwbyte  ;speichern des ersten bytes
 109         rjmp handle_end_inc
 110 h_readmemory_addr_byte1:  ;zweiters Addressbyte wird nicht gespeichert!
 111         ldi r_mode,OW_READ_MEMORY ;weiter zu read Memory
 112         ;;ldi r_bcount,1 ;ist unten
 113         ldi r_sendflag,1 ;jetzt sendet der Slave zum Master
 114         clr r_bytep
 115         rjmp h_readmemory2
 116 h_readmemory:
 117         lds r_bytep,addr
 118         inc r_bytep
 119         sts addr,r_bytep
 120         andi r_bytep,0x07
 121         breq h_readmemory_init_crc
 122 h_readmemory2:
 123         lds r_bytep,addr
 124         ;andi r_bytep,0x1F ist oben
 125         configZ pack,r_bytep
 126         ld   r_rwbyte,Z
 127         ;ldi r_bcount,1
 128         rjmp handle_end ;sendet das Byte und geht zu h_readmemory
 129 h_readmemory_init_crc:; init erstes CRC byte
 130         lds r_rwbyte,crc
 131         com r_rwbyte
 132         lds r_temp,crc+1
 133         com r_temp
 134         sts crcsave,r_temp
 135         ldi r_mode,OW_READ_MEMORY_CRC1
 136         ;ldi r_bcount,1
 137         rjmp handle_end
 138 h_readmemory_end:
 139         ldi  r_mode,OW_SLEEP
 140         clr r_sendflag
 141         rjmp handle_end
 142 h_readmemorycrc1:;init zweites CRC Byte
 143         lds r_rwbyte,crcsave
 144         ;ldi r_bcount,1
 145         ldi r_mode,OW_READ_MEMORY_CRC2
 146         rjmp handle_end
 147 h_readmemorycrc2:;weiteres senden..... nach zweitem Byte
 148         lds r_temp,addr
 149         andi r_temp,0xE0
 150         brne h_readmemory_end; ende des speichers
 151         ldi r_mode,OW_READ_MEMORY
 152         CRCInit1 ;Start with new CRC
 153         rjmp h_readmemory2
 154
 155 h_writememoryaddr:
 156         cpi r_bytep,0  ;erstes Adressbyte ?
 157         brne h_writememory_addr_byte1 ;nein dann weiter
 158         andi r_rwbyte,0x1F  ; nur Adressen zwischen 0 und 0x1F zulassen
 159         sts addr,r_rwbyte  ;speichern des ersten bytes
 160         inc r_bytep
 161         ;ldi r_bcount,1
 162         rjmp handle_end
 163 h_writememory_addr_byte1:  ;zweiters Addressbyte wird nicht gespeichert!
 164         ldi r_mode,OW_WRITE_MEMORY ;weiter zu read Memory
 165         ;ldi r_bcount,1 ;; _________________________________________________in handle_end integrieren.....
 166         lds r_bytep,addr
 167         rjmp handle_end ;read Memory Byte
 168 h_writememory:
 169         lds r_bytep,addr
 170         configZ pack,r_bytep
 171         st Z,r_rwbyte
 172         ;ldi r_bcount,1
 173         ldi r_mode,OW_WRITE_MEMORY_CRC1
 174         ldi r_sendflag,1 ;jetzt sendet der Slave zum Master
 175         lds r_rwbyte,crc
 176         com r_rwbyte
 177         lds r_temp,crc+1
 178         com r_temp
 179         sts crcsave,r_temp
 180         rjmp handle_end
 181 h_writememorycrc1:
 182         lds r_rwbyte,crcsave
 183         ;ldi r_bcount,1
 184         ldi r_mode,OW_WRITE_MEMORY_CRC2
 185         rjmp handle_end
 186 h_writememorycrc2:
 187         lds r_temp,addr
 188         configZ pack,r_temp
 189         ld r_rwbyte,Z
 190         ;ldi r_bcount,1
 191         ldi r_mode,OW_WRITE_MEMORY_READBACK
 192         rjmp handle_end
 193 h_writememoryreadback:
 194         ldi r_temp,0x00
 195         sts crc+1,r_temp
 196         lds r_temp,addr
 197         inc r_temp
 198         sts addr,r_temp
 199         sts crc,r_temp
 200         ldi r_sendflag,0
 201         ;ldi r_bcount,1
 202         ldi r_mode,OW_WRITE_MEMORY
 203         rjmp handle_end
 204
 205 h_convert:
 206         cpi r_bytep,0  ;erstes Adressbyte ?
 207         brne h_convert_byte1 ;nein dann weiter
 208         inc r_bytep
 209         sts pack+0x20,r_rwbyte
 210         ;ldi r_bcount,1
 211         rjmp handle_end
 212 h_convert_byte1: ;zweies byte glesen go crc#
 213         sts pack+0x21,r_rwbyte
 214         lds r_rwbyte,crc
 215         com r_rwbyte
 216         lds r_temp,crc+1
 217         com r_temp
 218         sts crcsave,r_temp
 219         ldi r_mode,OW_CONVERT_CRC1
 220         ;ldi r_bcount,1
 221         ldi r_sendflag,1
 222         rjmp handle_end
 223 h_convertcrc1:
 224         lds r_rwbyte,crcsave
 225         ;ldi r_bcount,1
 226         ldi r_mode,OW_CONVERT_CRC2
 227         rjmp handle_end
 228 h_convertcrc2:
 229         ldi r_temp,1
 230         sts gcontrol,r_temp
 231         ;ldi r_bcount,1
 232         ldi r_mode,OW_SLEEP
 233         clr r_sendflag
 234         rjmp handle_end
 235
 236
 237
 238
 239 #include "../common/OWPinInterrupt.s"
 240 .end