DS2450/OWDS2450.S

   1
   2 // Copyright (c) 2015, Tobias Mueller tm(at)tm3d.de
   3 // All rights reserved.
   4 //
   5 // Redistribution and use in source and binary forms, with or without
   6 // modification, are permitted provided that the following conditions are
   7 // met:
   8 //
   9 //  * Redistributions of source code must retain the above copyright
  10 //    notice, this list of conditions and the following disclaimer.
  11 //  * Redistributions in binary form must reproduce the above copyright
  12 //    notice, this list of conditions and the following disclaimer in the
  13 //    documentation and/or other materials provided with the
  14 //    distribution.
  15 //  * All advertising materials mentioning features or use of this
  16 //    software must display the following acknowledgement: This product
  17 //    includes software developed by tm3d.de and its contributors.
  18 //  * Neither the name of tm3d.de nor the names of its contributors may
  19 //    be used to endorse or promote products derived from this software
  20 //    without specific prior written permission.
  21 //
  22 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  23 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  24 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  25 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  26 // OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  27 // SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  28 // LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  29 // DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  30 // THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  31 // (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  32 // OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  33
  34 #define _CHANGEABLE_ID_
  35
  36 #include "../common/OWConfig.s"
  37 #include "../common/OWCRC16.s"
  38
  39 .extern pack,8
  40 .comm addr,1 ;zweites Adressbyte ist unnoetig (Warum auch immer fuer 32 Byte 16 Bit Adressen verwendet werden....)
  41 .comm crcsave,1 ; zwischenspeicherspeicher fuer crc nur zweites byte....
  42 //.extern  am2302_temp,2
  43
  44
  45
  46 .macro CHIP_INIT
  47 .endm
  48
  49 .macro COMMAND_TABLE
  50                 rjmp h_readmemoryaddr
  51                 rjmp h_readmemory
  52                 rjmp h_readmemorycrc1
  53                 rjmp h_readmemorycrc2
  54                 rjmp h_writememoryaddr
  55                 rjmp h_writememory
  56                 rjmp h_writememorycrc1
  57                 rjmp h_writememorycrc2
  58                 rjmp h_writememoryreadback
  59                 rjmp h_convert
  60                 rjmp h_convertcrc1
  61                 rjmp h_convertcrc2
  62 .endm
  63
  64 #include "../common/OWRomFunctions.s"
  65 #include "../common/OWTimerInterrupt.s"
  66
  67
  68
  69 ; Ab hier Geraeteabhaenging
  70 #define OW_READ_MEMORY_ADDR OW_FIRST_COMMAND+0
  71 #define OW_READ_MEMORY OW_FIRST_COMMAND+1
  72 #define OW_READ_MEMORY_CRC1 OW_FIRST_COMMAND+2
  73 #define OW_READ_MEMORY_CRC2 OW_FIRST_COMMAND+3
  74 #define OW_WRITE_MEMORY_ADDR OW_FIRST_COMMAND+4
  75 #define OW_WRITE_MEMORY OW_FIRST_COMMAND+5
  76 #define OW_WRITE_MEMORY_CRC1 OW_FIRST_COMMAND+6
  77 #define OW_WRITE_MEMORY_CRC2 OW_FIRST_COMMAND+7
  78 #define OW_WRITE_MEMORY_READBACK OW_FIRST_COMMAND+8
  79 #define OW_CONVERT OW_FIRST_COMMAND+9
  80 #define OW_CONVERT_CRC1 OW_FIRST_COMMAND+10
  81 #define OW_CONVERT_CRC2 OW_FIRST_COMMAND+11
  82
  83
  84 ;---------------------------------------------------
  85 ;       READ COMMAND and start operation
  86 ;---------------------------------------------------
  87
  88
  89 h_readcommand:
  90         clr r_bytep
  91 #ifndef _DIS_FLASH_
  92         FLASH_COMMANDS ; muss zu erst sein....
  93 #endif
  94         cset 0xAA,OW_READ_MEMORY_ADDR
  95         cset 0x55,OW_WRITE_MEMORY_ADDR
  96         cset 0x3C,OW_CONVERT
  97         FW_CONFIG_INFO
  98 #ifdef _CHANGEABLE_ID_
  99         CHANGE_ID_COMMANDS
 100 #endif
 101         ldi r_mode,OW_SLEEP
 102         rjmp handle_end
 103
 104
 105 h_readmemoryaddr:
 106         cpi r_bytep,0  ;erstes Adressbyte ?
 107         brne h_readmemory_addr_byte1 ;nein dann weiter
 108         andi r_rwbyte,0x1F  ; nur Adressen zwischen 0 und 0x1F zulassen
 109         sts addr,r_rwbyte  ;speichern des ersten bytes
 110         rjmp handle_end_inc
 111 h_readmemory_addr_byte1:  ;zweiters Addressbyte wird nicht gespeichert!
 112         ldi r_mode,OW_READ_MEMORY ;weiter zu read Memory
 113         ;;ldi r_bcount,1 ;ist unten
 114         ldi r_sendflag,1 ;jetzt sendet der Slave zum Master
 115         clr r_bytep
 116         rjmp h_readmemory2
 117 h_readmemory:
 118         lds r_bytep,addr
 119         inc r_bytep
 120         sts addr,r_bytep
 121         andi r_bytep,0x07
 122         breq h_readmemory_init_crc
 123 h_readmemory2:
 124         lds r_bytep,addr
 125         ;andi r_bytep,0x1F ist oben
 126         configZ pack,r_bytep
 127         ld   r_rwbyte,Z
 128         ;ldi r_bcount,1
 129         rjmp handle_end ;sendet das Byte und geht zu h_readmemory
 130 h_readmemory_init_crc:; init erstes CRC byte
 131         lds r_rwbyte,crc
 132         com r_rwbyte
 133         lds r_temp,crc+1
 134         com r_temp
 135         sts crcsave,r_temp
 136         ldi r_mode,OW_READ_MEMORY_CRC1
 137         ;ldi r_bcount,1
 138         rjmp handle_end
 139 h_readmemory_end:
 140         ldi  r_mode,OW_SLEEP
 141         clr r_sendflag
 142         rjmp handle_end
 143 h_readmemorycrc1:;init zweites CRC Byte
 144         lds r_rwbyte,crcsave
 145         ;ldi r_bcount,1
 146         ldi r_mode,OW_READ_MEMORY_CRC2
 147         rjmp handle_end
 148 h_readmemorycrc2:;weiteres senden..... nach zweitem Byte
 149         lds r_temp,addr
 150         andi r_temp,0xE0
 151         brne h_readmemory_end; ende des speichers
 152         ldi r_mode,OW_READ_MEMORY
 153         CRCInit1 ;Start with new CRC
 154         rjmp h_readmemory2
 155
 156 h_writememoryaddr:
 157         cpi r_bytep,0  ;erstes Adressbyte ?
 158         brne h_writememory_addr_byte1 ;nein dann weiter
 159         andi r_rwbyte,0x1F  ; nur Adressen zwischen 0 und 0x1F zulassen
 160         sts addr,r_rwbyte  ;speichern des ersten bytes
 161         inc r_bytep
 162         ;ldi r_bcount,1
 163         rjmp handle_end
 164 h_writememory_addr_byte1:  ;zweiters Addressbyte wird nicht gespeichert!
 165         ldi r_mode,OW_WRITE_MEMORY ;weiter zu read Memory
 166         ;ldi r_bcount,1 ;; _________________________________________________in handle_end integrieren.....
 167         lds r_bytep,addr
 168         rjmp handle_end ;read Memory Byte
 169 h_writememory:
 170         lds r_bytep,addr
 171         configZ pack,r_bytep
 172         st Z,r_rwbyte
 173         ;ldi r_bcount,1
 174         ldi r_mode,OW_WRITE_MEMORY_CRC1
 175         ldi r_sendflag,1 ;jetzt sendet der Slave zum Master
 176         lds r_rwbyte,crc
 177         com r_rwbyte
 178         lds r_temp,crc+1
 179         com r_temp
 180         sts crcsave,r_temp
 181         rjmp handle_end
 182 h_writememorycrc1:
 183         lds r_rwbyte,crcsave
 184         ;ldi r_bcount,1
 185         ldi r_mode,OW_WRITE_MEMORY_CRC2
 186         rjmp handle_end
 187 h_writememorycrc2:
 188         lds r_temp,addr
 189         configZ pack,r_temp
 190         ld r_rwbyte,Z
 191         ;ldi r_bcount,1
 192         ldi r_mode,OW_WRITE_MEMORY_READBACK
 193         rjmp handle_end
 194 h_writememoryreadback:
 195         ldi r_temp,0x00
 196         sts crc+1,r_temp
 197         lds r_temp,addr
 198         inc r_temp
 199         sts addr,r_temp
 200         sts crc,r_temp
 201         ldi r_sendflag,0
 202         ;ldi r_bcount,1
 203         ldi r_mode,OW_WRITE_MEMORY
 204         rjmp handle_end
 205
 206 h_convert:
 207         cpi r_bytep,0  ;erstes Adressbyte ?
 208         brne h_convert_byte1 ;nein dann weiter
 209         inc r_bytep
 210         sts pack+0x20,r_rwbyte
 211         ;ldi r_bcount,1
 212         rjmp handle_end
 213 h_convert_byte1: ;zweies byte glesen go crc#
 214         sts pack+0x21,r_rwbyte
 215         lds r_rwbyte,crc
 216         com r_rwbyte
 217         lds r_temp,crc+1
 218         com r_temp
 219         sts crcsave,r_temp
 220         ldi r_mode,OW_CONVERT_CRC1
 221         ;ldi r_bcount,1
 222         ldi r_sendflag,1
 223         rjmp handle_end
 224 h_convertcrc1:
 225         lds r_rwbyte,crcsave
 226         ;ldi r_bcount,1
 227         ldi r_mode,OW_CONVERT_CRC2
 228         rjmp handle_end
 229 h_convertcrc2:
 230         ldi r_temp,1
 231         sts gcontrol,r_temp
 232         ;ldi r_bcount,1
 233         ldi r_mode,OW_SLEEP
 234         clr r_sendflag
 235         rjmp handle_end
 236
 237
 238
 239
 240 #include "../common/OWPinInterrupt.s"
 241 .end