common/OWRomFunctionsDual.s

   1 // Copyright (c) 2017, Tobias Mueller tm(at)tm3d.de\r
   2 // All rights reserved. \r
   3 // \r
   4 // Redistribution and use in source and binary forms, with or without \r
   5 // modification, are permitted provided that the following conditions are \r
   6 // met: \r
   7 // \r
   8 //  * Redistributions of source code must retain the above copyright \r
   9 //    notice, this list of conditions and the following disclaimer. \r
  10 //  * Redistributions in binary form must reproduce the above copyright \r
  11 //    notice, this list of conditions and the following disclaimer in the \r
  12 //    documentation and/or other materials provided with the \r
  13 //    distribution. \r
  14 //  * All advertising materials mentioning features or use of this \r
  15 //    software must display the following acknowledgement: This product \r
  16 //    includes software developed by tm3d.de and its contributors. \r
  17 //  * Neither the name of tm3d.de nor the names of its contributors may \r
  18 //    be used to endorse or promote products derived from this software \r
  19 //    without specific prior written permission. \r
  20 // \r
  21 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS \r
  22 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT \r
  23 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR \r
  24 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT \r
  25 // OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, \r
  26 // SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT \r
  27 // LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, \r
  28 // DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY \r
  29 // THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT \r
  30 // (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE \r
  31 // OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. \r
  32 \r
  33 \r
  34 \r
  35 .macro cjmp val,addr\r
  36         cpi r_rwbyte,\val\r
  37         breq \addr\r
  38 .endm\r
  39 .macro cljmp val,addr; Weiter sprung, wenn das ziel zu weit entfernt fuer brxx\r
  40         cpi r_rwbyte,\val\r
  41         brne 1f\r
  42         rjmp \addr\r
  43 1:\r
  44 .endm\r
  45 \r
  46 .macro cset val,mod ;Nur der Mode wird gesetzt. Abkuerzung da oft nur das noch bleibt\r
  47         cpi r_rwbyte,\val\r
  48         brne 1f\r
  49         ldi r_mode,\mod\r
  50         rjmp handle_end\r
  51 1:\r
  52 .endm\r
  53 \r
  54 \r
  55 \r
  56 \r
  57 #define OW_SLEEP 0\r
  58 #define OW_READ_ROM_COMMAND 1\r
  59 #define OW_MATCHROM 2\r
  60 #define OW_SEARCHROMS 3  ;next send two bit\r
  61 #define OW_SEARCHROMR 4  ; next resive master answer\r
  62 #define OW_READ_COMMAND1 5\r
  63 #define OW_READ_COMMAND2 6\r
  64 #define OW_READ_COMMAND12 7 ;Skip ROM.... eigentlich nicht mit mehreren geraeten, aber bei loxone schon (CC 44)\r
  65 #define OW_FWCONFIGINFO1 8\r
  66 #define OW_FWCONFIGINFO2 9\r
  67 \r
  68 .comm idtable,64\r
  69 \r
  70 #ifdef _CHANGEABLE_ID_\r
  71 #define OW_WRITE_NEWID 10\r
  72 #define OW_READ_NEWID 11\r
  73 #define OW_SET_NEWID 12\r
  74 #define OW_FIRST_COMMAND 13\r
  75 .comm newid,8\r
  76 \r
  77    \r
  78 .macro CHANGE_ID_COMMANDS\r
  79         cset 0x75,OW_WRITE_NEWID\r
  80         cljmp 0xA7,hrc_set_readid\r
  81         cljmp 0x79,hrc_set_setid\r
  82 .endm\r
  83 \r
  84 \r
  85 #else\r
  86 #define OW_FIRST_COMMAND 10\r
  87 #endif\r
  88 \r
  89 #ifndef _DIS_FLASH_\r
  90 ; test auf run flasher command 0x88 in h_readcommand\r
  91 .macro FLASH_COMMANDS\r
  92         cpi r_rwbyte,0x88\r
  93         brne 1f\r
  94         rjmp hrc_jmp_flasher\r
  95 1: ldi r_temp,0 ;Anderes Kommando flashmarker zuruecksetzen...\r
  96         sts flashmarker,r_temp\r
  97 .endm\r
  98 #endif\r
  99 \r
 100 \r
 101 .macro FW_CONFIG_INFO1\r
 102         cljmp 0x85,hrc_fw_configinfo1\r
 103 .endm\r
 104 .macro FW_CONFIG_INFO2\r
 105         cljmp 0x85,hrc_fw_configinfo2\r
 106 .endm\r
 107 \r
 108 //#ifdef _CHANGEABLE_ID_ //--> ID vom EEPROM lesen auch wenn sie sich nicht ändern laesst\r
 109 ; lesen der ID aus dem EEPROM beim Start\r
 110 read_EEPROM_ID1:  \r
 111         ldi r_temp2,lo8(E2END)\r
 112         ldi zh,hi8(E2END)\r
 113         subi r_temp2,7\r
 114         out _SFR_IO_ADDR(EEARH), zh\r
 115         ldi r_bytep,0\r
 116         ldi  zl,lo8(owid1)       \r
 117     ldi  zh,hi8(owid1)\r
 118         rjmp read_EEPROM_ID_loop\r
 119 read_EEPROM_ID2:  \r
 120         ldi r_temp2,lo8(E2END)\r
 121         ldi zh,hi8(E2END)\r
 122         subi r_temp2,15\r
 123         out _SFR_IO_ADDR(EEARH), zh\r
 124         ldi r_bytep,0\r
 125         ldi  zl,lo8(owid2)       \r
 126     ldi  zh,hi8(owid2)\r
 127 read_EEPROM_ID_loop:\r
 128         sbic _SFR_IO_ADDR(EECR), EEPE\r
 129         rjmp read_EEPROM_ID_loop\r
 130         out _SFR_IO_ADDR(EEARL),r_temp2\r
 131         sbi _SFR_IO_ADDR(EECR), EERE\r
 132         in r_rwbyte,_SFR_IO_ADDR(EEDR)\r
 133         cpi r_rwbyte,0xFF\r
 134         breq read_EEPROM_ID_end\r
 135         st Z+,r_rwbyte\r
 136         inc r_bytep\r
 137         inc r_temp2\r
 138         cpi r_bytep,8\r
 139         brne read_EEPROM_ID_loop\r
 140 read_EEPROM_ID_end:\r
 141         ret\r
 142 //#endif\r
 143 \r
 144 \r
 145 \r
 146 \r
 147 \r
 148 \r
 149 \r
 150 handle_stable: \r
 151                 rjmp handle_end_no_bcount // sleep eventuell reset, nichts tun und auf Timeout warten\r
 152                 rjmp h_readromcommand \r
 153                 rjmp h_matchrom \r
 154                 rjmp h_searchroms \r
 155                 rjmp h_searchromr\r
 156                 rjmp h_readcommand1 \r
 157                 rjmp h_readcommand2\r
 158 #ifdef _HANDLE_CC_COMMAND_\r
 159                 rjmp h_readcommand12\r
 160 #else\r
 161                 rjmp handle_end_no_bcount\r
 162 #endif\r
 163                 rjmp h_fwconfiginfo1\r
 164                 rjmp h_fwconfiginfo2\r
 165 #ifdef _CHANGEABLE_ID_\r
 166                 rjmp h_writeid\r
 167                 rjmp h_readid\r
 168                 rjmp h_setid\r
 169 #endif\r
 170                 COMMAND_TABLE\r
 171 \r
 172 \r
 173 \r
 174 h_readromcommand:\r
 175         clr r_bytep\r
 176         cjmp 0x55,hrc_set_matchrom\r
 177         cjmp 0xF0,hrc_set_searchrom\r
 178         cjmp 0xEC,hrc_set_alarm_search\r
 179 #ifdef _HANDLE_CC_COMMAND_\r
 180         cjmp 0xCC,hrc_start_read_command12\r
 181 #endif\r
 182         rjmp handle_end_sleep\r
 183 \r
 184 #ifndef _DIS_FLASH_\r
 185 ;sprung zum flasher\r
 186 hrc_jmp_flasher:\r
 187         lds r_temp,flashmarker\r
 188         cpi r_temp,2\r
 189         brne hrc_jmp_flasher_inc\r
 190         JMP_FLASHER\r
 191 hrc_jmp_flasher_inc:\r
 192         inc r_temp\r
 193         sts flashmarker,r_temp\r
 194         rjmp handle_end_sleep\r
 195 #endif\r
 196 \r
 197 hrc_set_matchrom:\r
 198         ldi r_temp,3\r
 199         sts srbyte,r_temp ; Beide geraete nehmen an searchrom teil\r
 200         ldi r_mode,OW_MATCHROM\r
 201         rjmp handle_end\r
 202 \r
 203 \r
 204 \r
 205 hrc_set_searchrom:      \r
 206         ldi r_temp,3\r
 207         sts srbyte,r_temp ; Beide geraete nehmen an searchrom teil\r
 208         configZ idtable,r_bytep\r
 209         rjmp h_searchrom_next_bit\r
 210 \r
 211 hrc_start_read_command: ;Skip rom und Matchrom ok...\r
 212         CRCInit1\r
 213         lds r_temp,srbyte\r
 214         cpi r_temp,1\r
 215         breq hrc_start_read_command1\r
 216         cpi r_temp,2\r
 217         breq hrc_start_read_command2\r
 218         rjmp handle_end_sleep\r
 219 hrc_start_read_command1:\r
 220         ldi r_mode,OW_READ_COMMAND1\r
 221         rjmp handle_end\r
 222 hrc_start_read_command2:\r
 223         ldi r_mode,OW_READ_COMMAND2\r
 224         rjmp handle_end\r
 225 \r
 226 #ifdef _HANDLE_CC_COMMAND_\r
 227 hrc_start_read_command12:\r
 228         ldi r_mode,OW_READ_COMMAND12\r
 229         rjmp handle_end\r
 230 #endif\r
 231 \r
 232 hrc_set_alarm_search:\r
 233         lds r_temp,alarmflag\r
 234         tst r_temp\r
 235         brne hrc_set_searchrom ;alarm flag nicht 0 also gehe zu searchrom\r
 236         ; sonst tue nichts\r
 237         rjmp handle_end_sleep\r
 238 \r
 239 hrc_fw_configinfo1:\r
 240 #ifdef _NO_CONFIGBYTES_\r
 241         rjmp handle_end_sleep\r
 242 #else\r
 243         ldi r_mode,OW_FWCONFIGINFO1\r
 244         ldi r_sendflag,1\r
 245         CRCInit2\r
 246         rjmp h_fwconfiginfo1\r
 247 #endif\r
 248 \r
 249 hrc_fw_configinfo2:\r
 250 #ifdef _NO_CONFIGBYTES_\r
 251         rjmp handle_end_sleep\r
 252 #else\r
 253         ldi r_mode,OW_FWCONFIGINFO2\r
 254         ldi r_sendflag,1\r
 255         CRCInit2\r
 256         rjmp h_fwconfiginfo2\r
 257 #endif\r
 258 \r
 259 ;---------------------------------------------------\r
 260 ;   MATCH ROM\r
 261 ;---------------------------------------------------\r
 262         \r
 263 \r
 264 h_matchrom:\r
 265         lds r_bcount,srbyte\r
 266         sbrs r_bcount,0 ;ueberspringe wenn bit 1 =0 also geraet 1 nich mehr im rennen\r
 267         rjmp h_matchrom_id2\r
 268         configZ owid1,r_bytep\r
 269         ld r_temp2,Z\r
 270         cp r_temp2,r_rwbyte\r
 271         breq h_matchrom_id2\r
 272         cbr r_bcount,1 ; loesche geraet\r
 273         breq h_matchrom_sleep\r
 274 h_matchrom_id2:\r
 275         configZ owid2,r_bytep\r
 276         ld r_temp2,Z\r
 277         cp r_temp2,r_rwbyte\r
 278         breq hmr_next_byte\r
 279         cbr r_bcount,2 ; loesche geraet\r
 280         breq h_matchrom_sleep\r
 281 \r
 282 hmr_next_byte:\r
 283         sts srbyte,r_bcount\r
 284         cpi r_bytep,7\r
 285         breq hrc_start_read_command ;Starten von Read Command\r
 286         rjmp handle_end_inc\r
 287 \r
 288 h_matchrom_sleep:\r
 289         sts srbyte,r_bcount\r
 290         rjmp handle_end_sleep\r
 291 \r
 292 \r
 293 ;---------------------------------------------------\r
 294 ;   SEARCH ROM\r
 295 ;---------------------------------------------------\r
 296 \r
 297 \r
 298 h_searchrom_next_bit:  ;Setup next Bit of ID\r
 299         ld r_temp2,Z\r
 300         lds r_temp,srbyte  ;srbyte ist ein zeiger auf die bits fuer ein bit im Table\r
 301 h_searchrom_next_bit_l2:\r
 302         cpi r_temp,3\r
 303         breq h_searchrom_next_bit_l1\r
 304         lsr r_temp2\r
 305         lsr r_temp2\r
 306         inc r_temp\r
 307         rjmp h_searchrom_next_bit_l2\r
 308 h_searchrom_next_bit_l1:\r
 309         lsr r_temp2\r
 310         rol r_rwbyte  ; negiertes bit in rwbyte\r
 311         lsr r_temp2\r
 312         rol r_rwbyte  ; bit in rwbyte\r
 313         ldi r_sendflag,1\r
 314         ldi r_bcount,0x40 ; zwei bits sensden dann zu Searchromr \r
 315         ldi r_mode,OW_SEARCHROMR\r
 316         rjmp handle_end_no_bcount\r
 317 \r
 318 \r
 319 \r
 320 h_searchroms:  ; Modus Send zwei bit\r
 321         configZ idtable,r_bytep\r
 322         ld r_temp2,Z+\r
 323         lds r_temp,srbyte\r
 324         cpi r_temp,3\r
 325         breq h_searchroms_idd\r
 326         cpi r_temp,1\r
 327         breq h_searchroms_id1\r
 328         cpi r_temp,2\r
 329         breq h_searchroms_id2\r
 330         rjmp handle_end_sleep ; zur Sicherheit.....\r
 331 h_searchroms_idd:\r
 332         andi r_rwbyte,0x80\r
 333         breq h_searchroms_idd_zero\r
 334         ; Master send 1\r
 335         sbrc r_temp2,0 ;springe wenn nicht beide bits 0 (id 1 negiert und id 2 negiert)\r
 336         rjmp handle_end_sleep ;\r
 337         sbrc r_temp2,4  ;id1 set? then skip\r
 338         cbr r_temp,1  ; loesche bit 1 in srbyte\r
 339         sbrc r_temp2,2 ; springe wenn id 2 gesetzt ist\r
 340         cbr r_temp,2 ;  loesche bit 2 in srbyte \r
 341         sts srbyte,r_temp\r
 342         rjmp h_searchroms_idX_end\r
 343 h_searchroms_idd_zero:\r
 344         sbrc r_temp2,1 ;springe wenn nicht beide 1 (id 1  und id 2 )\r
 345         rjmp handle_end_sleep ;beide 1 gehe schlafen\r
 346         sbrs r_temp2,4  ;id1 0? then skip\r
 347         cbr r_temp,1  ; loesche bit 1 in srbyte\r
 348         sbrs r_temp2,2 ; springe wenn id 2  null ist\r
 349         cbr r_temp,2  ; loesche bit 2 in srbyte\r
 350         sts srbyte,r_temp\r
 351         rjmp h_searchroms_idX_end\r
 352 h_searchroms_id1:\r
 353         andi r_rwbyte,0x80\r
 354         breq h_searchroms_id1_zero\r
 355         ; Master send 1\r
 356         sbrs r_temp2,5  ;id1 set? then skip\r
 357         rjmp handle_end_sleep ;\r
 358         rjmp h_searchroms_idX_end\r
 359 h_searchroms_id1_zero:          \r
 360         sbrs r_temp2,4  ;id1 set? then skip\r
 361         rjmp handle_end_sleep ;\r
 362         rjmp h_searchroms_idX_end\r
 363 h_searchroms_id2:\r
 364         andi r_rwbyte,0x80\r
 365         breq h_searchroms_id2_zero\r
 366         ; Master send 1\r
 367         sbrs r_temp2,3  ;id1 set? then skip\r
 368         rjmp handle_end_sleep ;\r
 369         rjmp h_searchroms_idX_end\r
 370 h_searchroms_id2_zero:          \r
 371         sbrs r_temp2,2  ;id1 set? then skip\r
 372         rjmp handle_end_sleep ;\r
 373         rjmp h_searchroms_idX_end\r
 374 h_searchroms_idX_end:\r
 375         lds r_temp,srbyte\r
 376         tst r_temp\r
 377         brne h_searchroms_idX_end1\r
 378         rjmp handle_end_sleep\r
 379 h_searchroms_idX_end1:\r
 380         inc r_bytep\r
 381         cpi r_bytep,64\r
 382         breq h_searchrom_end_ok  ;unterschied nur das letzt bit wird wohl nie vorkommen\r
 383         rjmp h_searchrom_next_bit\r
 384 \r
 385 h_searchrom_end_ok:\r
 386         clr r_sendflag\r
 387         rjmp hrc_start_read_command\r
 388 \r
 389 h_searchromr:  ; stelle um auf empfangen\r
 390         clr r_sendflag\r
 391         ldi r_mode,OW_SEARCHROMS\r
 392         ldi r_bcount,0  ;gehe nach einem bit zu SEARCHROMS\r
 393         rjmp handle_end_no_bcount\r
 394 \r
 395 \r
 396 ;---------------------------------------------------\r
 397 ;   FW_CONFIG_INFO\r
 398 ;---------------------------------------------------\r
 399 \r
 400 h_fwconfiginfo1:\r
 401 #ifdef _NO_CONFIGBYTES_\r
 402 h_fwconfiginfo2:\r
 403         rjmp handle_end_sleep\r
 404 #else\r
 405         configZ config_info1,r_bytep\r
 406         rjmp h_fwconfiginfo_go\r
 407 h_fwconfiginfo2:\r
 408         configZ config_info2,r_bytep\r
 409 /*#ifdef _CRC16_\r
 410         cpi  r_bytep,24\r
 411         breq h_fwconfiginfo_crc\r
 412         cpi  r_bytep,26\r
 413         breq h_fwconfiginfo_all\r
 414 //h_fwconfiginfo_end:\r
 415         //configZ config_info1,r_bytep  //crc16 wird in config_info1 gespeichert, auch bei config_info2 \r
 416         configZ config_info2,r_bytep\r
 417         ld   r_rwbyte,Z\r
 418         rjmp handle_end_inc\r
 419 #endif\r
 420 */\r
 421 \r
 422 h_fwconfiginfo_go:\r
 423         cpi  r_bytep,24\r
 424         breq h_fwconfiginfo_crc\r
 425 #if defined(_CRC8_)  || defined( _CRC8_16_) \r
 426         cpi  r_bytep,25\r
 427         breq h_fwconfiginfo_all\r
 428 #elif defined _CRC16_\r
 429         cpi  r_bytep,26\r
 430         breq h_fwconfiginfo_all\r
 431 #else\r
 432         cpi  r_bytep,25\r
 433         breq h_fwconfiginfo_all\r
 434 #warning No CRC known code implemented\r
 435 #endif\r
 436 \r
 437 h_fwconfiginfo_end:\r
 438         //configZ config_info1,r_bytep  //crc16 wird in config_info1 gespeichert, auch bei config_info2 \r
 439         //configZ config_info1,r_bytep\r
 440         ld   r_rwbyte,Z\r
 441         rjmp handle_end_inc\r
 442 h_fwconfiginfo_crc:\r
 443 #ifdef _CRC8_ \r
 444         lds r_rwbyte,crc\r
 445         rjmp handle_end_inc\r
 446 #elif defined _CRC16_\r
 447         lds r_temp,crc\r
 448         com r_temp\r
 449         sts config_info1+24,r_temp\r
 450         lds r_temp,crc+1\r
 451         com r_temp\r
 452         sts config_info1+25,r_temp\r
 453         ldi r_mode,OW_FWCONFIGINFO1  //auch CRC vom Dev 2 wird in Configinfo 1 geschrieben also da weiter machen\r
 454         configZ config_info1,r_bytep\r
 455         ld   r_rwbyte,Z\r
 456         rjmp handle_end_inc\r
 457 \r
 458 #endif\r
 459 h_fwconfiginfo_all:\r
 460         rjmp handle_end_sleep\r
 461 #endif\r
 462 \r
 463 ;---------------------------------------------------\r
 464 ;   CHANGE ROM FUNCTIONS\r
 465 ;---------------------------------------------------\r
 466 \r
 467 \r
 468 #ifdef _CHANGEABLE_ID_\r
 469 \r
 470 h_writeid:\r
 471         configZ newid,r_bytep\r
 472         st   Z,r_rwbyte\r
 473         cpi  r_bytep,7\r
 474         breq h_writeid_all\r
 475         rjmp handle_end_inc\r
 476 h_writeid_all:\r
 477         rjmp handle_end_sleep\r
 478 \r
 479 \r
 480 hrc_set_readid:\r
 481         ldi r_mode,OW_READ_NEWID\r
 482         ldi r_sendflag,1\r
 483 h_readid:\r
 484         cpi  r_bytep,8\r
 485         breq h_readid_all\r
 486         configZ newid,r_bytep\r
 487         ld   r_rwbyte,Z\r
 488         rjmp handle_end_inc\r
 489 h_readid_all:\r
 490         clr  r_sendflag\r
 491         rjmp handle_end_sleep\r
 492 \r
 493 hrc_set_setid:\r
 494         ldi r_mode,OW_SET_NEWID\r
 495         ;ldi r_bytep,1 ;start to write in 2\r
 496         rjmp handle_end_inc ;set r_bytep to 1!!!\r
 497 \r
 498 h_setid:\r
 499         lds r_bcount,srbyte\r
 500         cpi r_bcount,2\r
 501         breq h_setid2\r
 502 h_setid1:\r
 503         configZ owid1,r_bytep\r
 504         rjmp h_setido\r
 505 h_setid2:\r
 506         configZ owid2,r_bytep\r
 507 h_setido:\r
 508         ld r_temp,Z\r
 509         cp r_rwbyte,r_temp\r
 510         brne h_setid_bad_code_all\r
 511         cpi r_bytep,1\r
 512         breq h_setid_set2\r
 513         cpi r_bytep,5 \r
 514         breq h_setid_set3\r
 515         cpi r_bytep,6\r
 516         breq h_setid_copy_id\r
 517         rjmp h_setid_bad_code_all ;sollte eigentlich nicht passieren\r
 518 h_setid_set2:\r
 519         ldi r_temp,3\r
 520         add r_bytep,r_temp\r
 521 h_setid_set3:\r
 522         inc r_bytep\r
 523         rjmp handle_end\r
 524 h_setid_copy_id:\r
 525         ldi r_temp2,lo8(E2END)\r
 526         ldi zh,hi8(E2END)\r
 527         ldi r_temp,7\r
 528         sbrc r_bcount,1\r
 529         ldi r_temp,15\r
 530         sub r_temp2,r_temp\r
 531         ;ldi r_temp,0 ;kommt nicht vor das ein E2ROM genau n*256+(0 bis 7) byte gross ist\r
 532         ;sbc zh\r
 533         out _SFR_IO_ADDR(EEARH),zh\r
 534         ldi zl,lo8(newid)\r
 535         ldi zh,hi8(newid)\r
 536         ldi r_bytep,0\r
 537 h_setid_EEPROM_write:\r
 538         sbic _SFR_IO_ADDR(EECR), EEPE   \r
 539         rjmp h_setid_EEPROM_write\r
 540         ldi r_temp, (0<<EEPM1)|(0<<EEPM0)\r
 541         out _SFR_IO_ADDR(EECR), r_temp\r
 542         ;nur adresse L schreiben H bleibt aus oben genannten grund gleich.\r
 543         out _SFR_IO_ADDR(EEARL),r_temp2\r
 544         ld  r_rwbyte,Z+\r
 545         out _SFR_IO_ADDR(EEDR), r_rwbyte\r
 546         sbi _SFR_IO_ADDR(EECR), EEMPE\r
 547         sbi _SFR_IO_ADDR(EECR), EEPE\r
 548         inc r_bytep\r
 549         inc r_temp2\r
 550         cpi r_bytep,8\r
 551         brne h_setid_EEPROM_write\r
 552         //rcall read_EEPROM_ID1\r
 553         //rcall read_EEPROM_ID2\r
 554         push r_idm1\r
 555         push r_idm2\r
 556         push xl\r
 557         push xh\r
 558         rcall init_idtable\r
 559         pop xh\r
 560         pop xl\r
 561         pop r_idm2\r
 562         pop r_idm1\r
 563 h_setid_bad_code_all:\r
 564         rjmp handle_end_sleep\r
 565 \r
 566 \r
 567 \r
 568 #endif\r
 569 \r
 570 \r
 571 spause:\r
 572         nop\r
 573         nop\r
 574         nop\r
 575         nop\r
 576         ret\r
 577 \r
 578 \r
 579 .global OWINIT\r
 580 OWINIT:\r
 581         \r
 582 ; check for bootloader jumper\r
 583         ;vor allen anderen Registerconfigs\r
 584         push r_temp\r
 585 #ifndef _DIS_FLASH_\r
 586         CHECK_BOOTLOADER_PIN \r
 587 #endif\r
 588         HW_INIT  //Microcontroller specific\r
 589         CHIP_INIT //1-Wire device specific\r
 590         pop r_temp\r
 591 init_idtable:\r
 592         push yl\r
 593         push yh\r
 594         push r_temp\r
 595         push r_rwbyte\r
 596         push r_idn1\r
 597         push r_idn2\r
 598 //#ifdef _CHANGEABLE_ID_\r
 599         rcall read_EEPROM_ID1\r
 600         rcall read_EEPROM_ID2\r
 601 //#endif\r
 602         ldi r_bytep,8\r
 603         ldi r_temp,0\r
 604         ldi  zl,lo8(idtable)\r
 605     ldi  zh,hi8(idtable)\r
 606         ldi  xl,lo8(owid1)\r
 607         ldi  xh,hi8(owid1)\r
 608         ldi      yl,lo8(owid2)\r
 609         ldi  yh,hi8(owid2)\r
 610 owinit_odgen1:\r
 611         ld r_idm1,X+\r
 612         ld r_idm2,Y+\r
 613         mov r_idn1,r_idm1\r
 614         com r_idn1\r
 615         mov r_idn2,r_idm2\r
 616         com r_idn2\r
 617         ldi r_bcount,8\r
 618         mov r_temp,r_idm1\r
 619         and r_temp,r_idm2\r
 620         mov r_temp2,r_idn1\r
 621         and r_temp2,r_idn2\r
 622 owinit_odgen2:\r
 623         ldi r_mode,0\r
 624         lsr r_idm1\r
 625         rol r_mode  ;6. Bit id1 \r
 626         lsr r_idn1  \r
 627         rol r_mode ; 5. Bit id1negiert\r
 628         lsr r_idm2\r
 629         rol r_mode  ;;4. Bit id2 \r
 630         lsr r_idn2  \r
 631         rol r_mode  ;3. Bit id2 negiert\r
 632         lsr r_temp \r
 633         rol r_mode ;zweites bit  id1 und id2\r
 634         lsr r_temp2\r
 635         rol r_mode   ;erstes bit id1 negiert und id2  negiert\r
 636         st  Z+,r_mode\r
 637         dec r_bcount\r
 638         brne owinit_odgen2\r
 639         dec r_bytep\r
 640         brne owinit_odgen1\r
 641         ;copy ids in config bytes\r
 642 #ifndef _NO_CONFIGBYTES_\r
 643         ldi  xl,lo8(owid1)\r
 644         ldi  xh,hi8(owid1)\r
 645         ldi      yl,lo8(config_info2+17)\r
 646         ldi  yh,hi8(config_info2+17)\r
 647         ldi r_temp,7\r
 648 owinit_cpconfig1:\r
 649         ld r_rwbyte,X+\r
 650         st Y+,r_rwbyte\r
 651         dec r_temp\r
 652         brne owinit_cpconfig1\r
 653         ldi  xl,lo8(owid2)\r
 654         ldi  xh,hi8(owid2)\r
 655         ldi      yl,lo8(config_info1+17)\r
 656         ldi  yh,hi8(config_info1+17)\r
 657         ldi r_temp,7\r
 658 owinit_cpconfig2:\r
 659         ld r_rwbyte,X+\r
 660         st Y+,r_rwbyte\r
 661         dec r_temp\r
 662         brne owinit_cpconfig2\r
 663 #endif\r
 664 \r
 665         ldi r_temp,0\r
 666         sts mode,r_temp\r
 667         sts bcount,r_temp\r
 668         sts alarmflag,r_temp\r
 669         RESETZEROMARKER\r
 670         pop r_idn2\r
 671         pop r_idn1\r
 672         pop r_rwbyte\r
 673         pop r_temp\r
 674         pop yh\r
 675         pop yl\r
 676         \r
 677         ret\r
 678 \r
 679 .global EXTERN_SLEEP\r
 680 EXTERN_SLEEP:\r
 681         cli\r
 682         push r_temp\r
 683         ldi r_temp,0\r
 684         sts mode,r_temp ;SLEEP\r
 685         sts gcontrol,r_temp\r
 686         sts sendflag,r_temp\r
 687         sts bcount,r_temp\r
 688         RESETZEROMARKER\r
 689         pop r_temp\r
 690         sei\r
 691         ret